;+
; NAME:
;	vu_stereoview
; PURPOSE:
;	Makes remote view of density and fish-eye map of
;	the Thomson scattering brightness
;	as seen from Stereo spacecraft
; CATEGORY:
;	sat/idl/util/vupack
; CALLING SEQUENCE:
	PRO vu_stereoview, hdr, ff, ut0=ut0, ihdr=ihdr,	$
		density		= density	, $
		brightness	= brightness, $
		ips_glevel	= ips_glevel, $
		degrees 	= degrees	, $
		fovsize 	= fovsize	, $
		sun_offset	= sun_offset, $
		volsize 	= volsize	, $
		full_color	= full_color, $
		full_range	= full_range, $
		full_opa	= full_opa	, $
		behind		= behind	, $
		earth		= earth 	, $
		delta_loc	= delta_loc , $
		silent		= silent	, $
		_extra		= _extra
; INPUTS:
;	hdr
;	ff
; OPTIONAL INPUT PARAMETERS:
;	/behind 	 			select Stereo B (default: Stereo A)
;	/degrees				if set, angles are in degrees
;	/brightness 			makes Thomson scattering brightness map
;	/ips_glevel				makes IPS g-level map
;	fovsize=fovsize 		scalar; type: float: default: 35 deg
;								field-of-view halfwidth
;	sun_offset=sun_offset	scalar; type: float: default: 53.3 deg
;								offset from Sun in ecliptic longitude for
;								viewing direction
;	silent		= silent	controls amount of informational
;						 	message
;
;	volsize=volsize
;	volsize 	= volsize
;	full_color	= full_color
;	full_range	= full_range
;	full_opa	= full_opa
; INCLUDE:
	@compile_opt.pro		; On error, return to caller
; EXTERNAL:
; CALLS:
;	InitVar, ToDegrees, vu_getdata, vu_type_insitu
;	vu_get, big_eph, AngleRange, vu_remoteview
;	SubArray
; PROCEDURE:
;	By default images are displayed on the screen.
;	For ways to save images, see href=RemoteView_Display2D=
;	and href=RemoteView_Display3D=, especially keywords
;	base_dir and base_name, and the image type keywords
;	for href=RemoteView_Init_View= (/png, /gif, etc)
; MODIFICATION HISTORY:
;	SEP-2008, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
;-

InitVar, behind, /key
InitVar, earth , /key
InitVar, silent, 0
InitVar, density   , /key
InitVar, brightness, /key
InitVar, ips_glevel, /key

density OR= brightness OR ips_glevel

dpm = ToDegrees(degrees=degrees)

InitVar, fovsize	, 70.0d0/2/dpm		; Stereo FOV

InitVar, volsize	, [0,3]
InitVar, full_color , [125,225]
InitVar, full_range	, [4.0,8.00]
InitVar, full_opa	, [0.0,0.07]

InitVar, sun_offset, 53.3d0/dpm*(1-earth)
pi = 180.0d0/dpm

utt = vu_getdata(hdr, ff, ut0=ut0, ihdr=ihdr, count=count, silent=silent, _extra=_extra)
IF count EQ 0 THEN RETURN

; If keyword brightness is set, then make sure that the density is processed

type = vu_type_insitu('earth_remoteview',	$
	density=density,		$
	_extra=_extra)

help,/struct,type

IF n_elements(type) NE 1 THEN message, 'oops'
voxel = 2+(brightness OR ips_glevel)

CASE 1 OF
brightness: f3dfnc = 'ThomsonBrightness'
ips_glevel: w3dfnc = 'IPS_hlevel_w'
ELSE:
ENDCASE

FOR i=0,n_elements(hdr)-1 DO BEGIN

	tt = vu_get(hdr[i],/uttime)

	location = big_eph(tt,	$
		body = 'Stereo '+(['A','B'])[behind],	$
		/to_ecliptic	, $
		/to_sphere		, $
		degrees=degrees , $
		/precess	 	, $
		/onebody		, $
		/silent 		)

	earth_loc = big_eph(tt,	$
		body = 'Earth'	, $
		/to_ecliptic	, $
		/to_sphere		, $
		degrees=degrees , $
		/precess		, $
		/onebody		, $
		/silent 		)

	CASE earth OF

	0: direction = [location[0]+pi+sun_offset*(1-2*behind),0.0d0]

	1: BEGIN
		location  = earth_loc
		direction = [location[0]+pi+sun_offset,0.0d0]
	END

	ENDCASE

	direction[0] = AngleRange(direction[0],degrees=degrees)

	IF IsType(delta_loc,/defined) THEN location += delta_loc

	print,	$
		'Time     : '+TimeGet(TT,/ymd,upto=TimeUnit(/minutes)),	+ $
		'Location : ' +	$
		'Lng='   ,location[0]*dpm, ' deg; '	+ $
		'Lat='   ,location[1]*dpm, ' deg; '	+ $
		'R='     ,location[2]	 , ' AU',	  $
		'Direction: '						+ $
		'Lng='	 ,direction[0]*dpm, ' deg; '+ $
		'Lat='	 ,direction[1]*dpm, ' deg',	  $
		'Earth    : '						+ $
		'Lng='	 ,earth_loc[0]*dpm, ' deg; '+ $
		'Lat='	 ,earth_loc[1]*dpm, ' deg; '+ $
		'R='     ,earth_loc[2]	  , ' AU',	  $
			format='(8X,A, /, 8X,3(A,F6.2),A, /, 8X,2(A,F6.2),A, /, 8X,3(A,F6.2),A)'

	vu_remoteview, hdr[i], ff[*,*,*,*,i], $
		type_ff 	= type			, $
		location	= location		, $
		direction	= direction 	, $
		degrees 	= degrees		, $
		/ecliptic					, $
		/eqangle					, $
		fovsize 	= fovsize		, $
		volsize 	= volsize		, $
		full_color	= full_color	, $
		full_range	= full_range	, $
		full_opa	= full_opa 		, $
		charsize	= type.charsize , $
		_extra		= _extra		, $
		view_nr 	= i				, $
		voxel		= voxel 		, $
		f3dfnc		= f3dfnc		, $
		w3dfnc		= w3dfnc		, $
		losarg		= losarg

ENDFOR

RETURN  &  END