;+
; NAME:
;	ThomsonBase
; PURPOSE:
;	(Used internally only)
;	Determines the intensity scattered from single coronal electron by Thomson scattering
; CALLING SEQUENCE:
	FUNCTION ThomsonBase, ElSun, SinChi, U, P, It, Itr
; INPUTS:
;	ElSun		array	distance Sun-observer (in solar radii)
;	SinChi		array	sine of angle Sun-Electron-Observer
;	U			array	limb darkening coefficient
; OUTPUTS:
;	Result		 array	scattered intensity
;	P			array	polarization; P=Itr/ThomsonBase (-1<=P<=1)
;	Itr			array	tangential minus radial intensity; same units as ThomsonBase.
;	It			array	radial intensity; same units as ThomsonBase
; INCLUDE:
	@compile_opt.pro		; On error, return to caller
; CALLS:
;	ThomsonSoup
; PROCEDURE:
; >	Based on Chapter 6, Section B of Billings' "A guide to the solar corona" (p. 150)
;
;	Sigma	= Thomson cross section=7.96x10^-26 cm^2/sterad
;	Omega	= angular size of Sun from electron
;	Chi		= angle Sun-Electron-Observer
;	I0		= intensity at disk center
;	RSun	= solar radius = 7x10^10 cm
;
;	Billings specifies the scattered intensity in the form
;		I=0.5*Pi*Sigma*I0*Func(Omega,Chi) (erg/s/sterad)
;	This subroutine only deals with Func(Omega,Chi):
;		From Eq. 18: It  = (1-u)*CC+u*DD
;		From Eq. 19: Itr = sin^2(Chi)*[(1-u)AA+u*DD]
; >	The last two arguments (It, Itr) are returned for use by function ThomsonIntegral.
; MODIFICATION HISTORY:
;	JUL-1996, Paul Hick (UCSD)
;-

ThomsonSoup, ElSun, U, It, Itr

Itr *= SinChi*SinChi	 		; Eq. (19), It-Ir

Base = It+It-Itr				; It+Ir
P = Itr/Base					; (It-Ir)/(It+Ir)

RETURN, Base  &  END