;+
; NAME:
;	CvSky_IHG
; PURPOSE:
;	Euler angles for Ecliptic to IHG conversion
; CATEGORY:
;	smei/gen/idl/ephem
; CALLING SEQUENCE:
	FUNCTION CvSky_IHG, UT, degrees=degrees
; INPUTS:
;	UT		array[n]; type: time structure
; OPTIONAL INPUT PARAMETERS:
;	/degrees	if set all angles are in degrees (default: radians)
; OUTPUTS:
;	abc		array[3,n]; type: float
;			Euler angles
; INCLUDE:
	@compile_opt.pro		; On error, return to caller
; CALLS:
;	ToDegrees, TimeGet, TimeUnit, SuperArray, SubArray
; SEE ALSO:
;	CvSky_Heliographic
; PROCEDURE:
;	The IHG z-axis is along the solar rotation axis (solar north).
;	The x-axis is toward the ascending node of the solar equator
;	on the ecliptic. See
;	http://nssdcftp.gsfc.nasa.gov/miscellaneous/documents/b46547.txt
;	and Burlaga, "MHD Processes in the Outer Heliosphere",
;		Space Sci. Rev. 39, 255-316, 1984.
;	Note that the nssdc website says:
;	"The X(IHG) axis drifts slowly with time, approximately one
;	degree per 72 years", while the Burlaga paper says (p. 260)
;	".. we shall take the X(IHG) axis along the direction of the
;	ascending node in 1900". I.e. the Burlaga paper seems to want
;	the X(IHG) axis fixed at epoch 1900.
;	Here we follow the description of the website.
;	The ecliptic longitude for the ascending node and the
;	inclination of equator to ecliptic are from
;	R. Green, "Spherical astronomy", p. 431
; MODIFICATION HISTORY:
;	JUN-2008, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
;-

; A[0,*] = -90 deg + ecliptic longitude of ascending node of solar equator on ecliptic
; A[1,*] = inclination of solar equator to ecliptic
; A[2,*] = 90 deg

Y = TimeGet(UT,TimeUnit(/year),/scalar)-1850+(TimeGet(UT,/doy,/scalar)-1.0d0)/365.25d0

A = SuperArray(0*Y,3,/lead)

A = SubArray(A, element=0, add=-16.333333d0+0.5025d0*Y/36.0d0)
A = SubArray(A, element=1, add=  7.25d0)
A = SubArray(A, element=2, add= 90.00d0)

RETURN, A/ToDegrees(degrees=degrees)  &  END