FUNCTION CvSky_Equatorial, UT, degrees=Degrees
;+
; NAME:
;	CvSky_Equatorial
; PURPOSE:
;	Euler angles for Ecliptic --> Equatorial conversion
; CATEGORY:
;	smei/gen/idl/ephem
; CALLING SEQUENCE:
;	abc = CvSky_Equatorial(UT [, /degrees)
; INPUTS:
;	UT			array[n]; type: time structure
; OPTIONAL INPUT PARAMETERS:
;	/degrees	if set, all angles are in degrees (default: radians)
; OUTPUTS:
;	abc			array[3,n]; type: double
;					Euler angles for converting from
;					ecliptic to equatorial coordinates
; INCLUDE:
	@compile_opt.pro		; On error, return to caller
; CALLS:
;	ToDegrees, TimeGet, SubArray, SuperArray
; PROCEDURE:
;	Angle ecliptic-equator as in:
;	Spherical Astronomy, R.M. Green, Cambridge UP, p. 220, eq 9.25
; MODIFICATION HISTORY:
;	AUG-2002, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
;-

T = 0.01d0*(TimeGet(UT, /jepoch, /scalar)-2000.0d0)		; Julian centuries since J2000.0

A = SuperArray(0d0*T, 3, /lead)

A = SubArray(A, element=0, add= 90.0d0)
A = SubArray(A, element=1, add= 23.43929111d0-(46.815d0+(0.001d0-0.002d0*T)*T)*T/3600.0d0 )
A = SubArray(A, element=2, add=-90.0d0)

A = A/ToDegrees(degrees=Degrees)

RETURN, A  &  END