;+
; NAME:
;	run_movie
; PURPOSE:
;	IDL main program to create gif animations. Run on Linux as a cron job.
; CATEGORY:
;	pro/tool
; CALLING SEQUENCE:
;	idl $pro/run_movie
; INPUTS:
;	(none)
; OUTPUTS:
;	(none)
; CALLS:
;	forecast_movie, jpl_body, vu_prefix, forecast_env
; RESTRICTIONS:
;	Can only be run on Linux
;	idl_startup.pro needs to be run. This requires that the environment
;	variable IDL_STARTUP is set.
; PROCEDURE:
;	This is run as part of the cron job bash=sync_daily_ips= after new
;	hourly-averaged tomography files have been created.
; MODIFICATION HISTORY:
;	APR-2000, Paul Hick (UCSD/CASS)
;	SEP-2002, Paul Hick (UCSD/CASS)
;		Added magnetic field movies for corotating tomography
;		Added magnetic field movies for time-dependent tomography
;	JUL-2004, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
;		Introduced functions vu_prefix and forecast_env for better
;		external control of input files.
;-

!TheTerminal = 'Z'

planets = [	$
		jpl_body(/mercury,/string) , $
		jpl_body(/venus	 ,/string) , $
		jpl_body(/mars	 ,/string) , $
		big_body('Stereo A'		 ) , $
		big_body('Stereo B'		 )   $
	]

silent = getenv('SILENT')
silent = silent EQ '' ? 2 : fix(silent)

ftp = 0

nv_prefix_slow = vu_prefix(silent=silent)
nv_prefix_fast = vu_prefix('nv3h',/fast,silent=silent)

forecast_env, 'slow', /magnetic, bb_prefix_slow, silent=silent
forecast_env, 'fast', /magnetic, bb_prefix_fast, silent=silent

tmp = is_running('/idl -quiet run_movie', count=count, silent=silent)
IF count GT 1 THEN exit

say, threshold=2, silent=silent, $
	'==== '+TimeGet(TimeSystem(/silent),format='MN/DD hh:mm')	+ $
	' Slow: movies for velocity and density'

forecast_movie, $ 
	ftp		= ftp		, $
	silent	= silent	, $
	/png				, $
	/gif				, $
	planets	= planets	, $
	filter	= nv_prefix_slow

say, threshold=2, silent=silent, $
	'==== '+TimeGet(TimeSystem(/silent),format='MN/DD hh:mm')	+ $
	' Fast: movies for velocity and density'

forecast_movie, /fast	, $
	ftp		= ftp		, $
	silent	= silent	, $
	/png				, $
	/gif				, $
	planets	= planets	, $
	filter	= nv_prefix_fast

say, threshold=2, silent=silent, $
	'==== '+TimeGet(TimeSystem(/silent),format='MN/DD hh:mm')	+ $
	' Slow: movies for radial and tangential magnetic field'

FOR i=0,n_elements(bb_prefix_slow)-1 DO	$
	forecast_movie, $
		ftp			= ftp				, $
		silent		= silent			, $
		/png							, $
		/gif							, $
		planets		= planets			, $
		filter		= bb_prefix_slow[i]	, $
		nv_filter	= nv_prefix_slow	, $
		/magnetic						, $
		env_filter	= 'bb_filter'

say, threshold=2, silent=silent, $
	'==== '+TimeGet(TimeSystem(/silent),format='MN/DD hh:mm')	+ $
	' Fast: movies for radial and tangential magnetic field'

FOR i=0,n_elements(bb_prefix_fast)-1 DO	$
	forecast_movie, /fast, $
		ftp			= ftp				, $
		silent		= silent			, $
		/png							, $
		/gif							, $
		planets		= planets			, $
		filter		= bb_prefix_fast[i]	, $
		nv_filter	= nv_prefix_fast	, $
		/magnetic						, $
		env_filter	= 'bb_filter'

exit					; Exit IDL