;+
; NAME:
;	qvu_fixgrid
; PURPOSE:
;	Destroys qvu widget
; CATEGORY:
;	Widget qvu
; CALLING SEQUENCE:
	PRO qvu_Fixgrid, state, event
; INPUTS:
;	state		array[1]; type: structure
;					qset_page state structure
;	event		array[1]; type: structure
;					event structure send by 'Done' widget
; OUTPUTS:
;	(none)
; INCLUDE:
	@compile_opt.pro					; On error, return to caller
; SIDE EFFECTS:
; PROCEDURE:
; MODIFICATION HISTORY:
;	SEP-2001, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
;-

widget_control, state.wid_fixgrid , set_uvalue=event.select

widget_control, state.wid_pole_lng, get_value=lng, get_uvalue=orig_lng
widget_control, state.wid_pole_lat, get_value=lat, get_uvalue=orig_lat
widget_control, state.wid_pole_rad, get_value=rad, get_uvalue=orig_rad
widget_control, state.wid_pole_tim, get_value=tim, get_uvalue=orig_tim

IF event.select THEN BEGIN
	widget_control, state.wid_pick, get_uvalue=hdr, /no_copy

	nlng = hdr[0].nlng
	nlat = hdr[0].nlat
	nrad = hdr[0].nrad
	ntim = n_elements(hdr)

	rmin = hdr[0].distance_start
	rmax = rmin+(nrad-1)*hdr[0].distance_step

	widget_control, state.wid_pick, set_uvalue=hdr, /no_copy


; When fixgrid is the plane is set to the solar equator
; (i.e. pole to solar north).

	widget_control, state.wid_pole_lng, set_value=[     0,lng[1],lng[2],  nlng]
	widget_control, state.wid_pole_lat, set_value=[    90,    90,    90,lat[3]]
	widget_control, state.wid_pole_rad, set_value=[     0,  rmin,  rmax,  nrad]
	widget_control, state.wid_pole_tim, set_value=[tim[0],tim[1],tim[2],  ntim]

	widget_control, state.wid_synoptic, get_uvalue=set
	widget_control, state.wid_pole_rad, sensitive=set

ENDIF ELSE BEGIN

	widget_control, state.wid_pole_lng, set_value=[lng[0],orig_lng[1:*]]
	widget_control, state.wid_pole_lat, set_value=[lat[0],orig_lat[1:*]]
	widget_control, state.wid_pole_rad, set_value=[rad[0],orig_rad[1:*]]
	widget_control, state.wid_pole_tim, set_value=[tim[0],orig_tim[1:*]]

ENDELSE

RETURN  &  END