;+
; NAME:
;	ThomsonRadialFilter
; PURPOSE:
;	
; CATEGORY:
;	sat/idl/toolbox/thomson
; CALLING SEQUENCE:
	FUNCTION ThomsonRadialFilter, elo_sun, degrees=degrees, elo_one=elo_one
; INPUTS:
;	elo_sun		array; type: float
;					elongations (angle between line of sight and
;					direction to Sun).
; OPTIONAL INPUT PARAMETERS:
;	elo_one=elo_one
;				scalar; type: float: default: 90 degrees
;					elongation at which radial filter has value of unity.
;					i.e. the filter scales to equivalent brightness at
;					this elongation
;	/degrees	if set, then elo_sun should be in degrees
; OUTPUTS:
;	F			array of same type as 'elo_sun'; type: float
;					radial filter; dividing by F should remove the steep dropoff
;					in the Thomson scattering brightness.
; INCLUDE:
	@compile_opt.pro	; On error, return to caller
; CALLS:
;	ToRadians, IsType
; PROCEDURE:
;	Currently the radial filter is the dropoff with elongation in a 1/r^2
;	density in the limit of small angular size of the Sun.
; MODIFICATION HISTORY:
;	FEB-2002, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
;-

rpm = ToRadians(degrees=degrees)

CASE IsType(elo_one,/defined) OF
0: elo = !pi/2
1: elo = elo_one[0]*rpm
ENDCASE

s  = sin(elo)			; Thomson scattering brightness drops off as sin^3 (elo)
c  = cos(elo)
s1 = 5.0/8.0*( (1-0.4*s*s)*c+(!pi-elo)/s)/(s*s)

elo = elo_sun*rpm

s  = sin(elo)			; Thomson scattering brightness drops off as sin^3 (elo)
c  = cos(elo)
s  = 5.0/8.0*( (1-0.4*s*s)*c+(!pi-elo)/s)/(s*s)

RETURN, s/s1  &  END