;+
; NAME:
;	nagoya_plotg2d
; CALLING SEQUENCE:
	PRO nagoya_plotg2d, r, glevel, color=color, source=source
; INCLUDE:
	@compile_opt.pro		; On error, return to caller
;-

unit   = 2*sqrt(2.0)			; Function Fisheye maps elongation maxelo
maxelo = !pi/2				; .. to radial distance 2*sqrt(2)

range  = 1.05*unit*[-1,1]

plot, [0], [0], xstyle=5, ystyle=5, /nodata, /noerase,	$
	xrange = -range, yrange = range, position = [0.1,0.05,1.0,0.95]

i = findgen(33)*(!pi*2/32.0)
y = cos(i)
z = sin(i)

xyouts, /norm, 0.84*[1,1,1,1]+.05, .05*(1+indgen(4))-.01, ['<1.0','1.0-1.3','1.3-2.0','>2.0']

usersym, y, z
FOR i=1,4 DO plots, /norm, [0.84], i*[0.05], psym=7+(i NE 1), syms=i-1

usersym, y, z, /fill

; r[0,*]	heliocentric ecliptic latitude point P
; r[1,*]	heliocentric ecliptic longitude point P relative to Sun-Earth line
; r[2,*]	heliocentric distance point P

r = CvPointOnLos(r, newelo=elo)					; Convert to geocentric coordinates
r = FishEye(r[0:1,*], maxelo=maxelo, dabg=0)	; Convert to 'fish-eye' coordinates

psym  = 7*(glevel LE 1  ) + 8*(glevel GT 1)
symsi = 1*(glevel LE 1.3) + 2*(glevel GT 1.3 AND glevel LT 2.0) + 3*(glevel GE 2.0)

FOR i=0,n_elements(glevel)-1 DO BEGIN
	;IF glevel[i] NE 0 AND elo[i] GT 0.2*maxelo THEN BEGIN
	IF glevel[i] NE 0 THEN BEGIN
		yi = r[0,i]
		zi = r[1,i]
		plots, [yi], [zi], psym=psym[i], symsi=symsi[i], color=color[i]
  		xyouts, yi, zi, source[i], si=0.8, align=-.25
	ENDIF
ENDFOR

plots, unit*[-1,1,0,0,0], unit*[0,0,0,1,-1]

i = findgen(361)/!radeg
y = cos(i)*0.25*unit
z = sin(i)*0.25*unit

FOR i=1,4 DO plots, y*i, z*i, linestyle=i ne 4

RETURN  &  END