C+
C NAME:
C	Time2JEpoch
C PURPOSE:
C	Converts Julian epoch to 2-element standard time and v.v.
C CATEGORY:
C	gen/for/lib
C CALLING SEQUENCE:
	subroutine Time2JEpoch(id,t,jepoch)
C INPUTS:
C	t(2)		integer			times
C OUTPUTS
C	jepoch		double precision	Julian epoch
C CALLS:
C	Time2TwoThousand, Time2Day8
C PROCEDURE:
C	J2000.0 = 2000 January 1.5d TDB = JD 2451545.0
C MODIFICATION HISTORY:
C	OCT-2003, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
C-
	    integer		t(2)
	    integer		u(2)
	    double precision	jepoch

	if (mod(id,2) .eq. 0) then		! Time ---> Julian epoch

	    call Time2TwoThousand(0,t,u)	! Shift origin to 2000 Jan 1, 0 UT

	    call Time2Day8(0,u,jepoch)

	    jepoch = (jepoch-0.5d0)/365.25d0
	    if (id .lt. 2) jepoch = jepoch+2000.0d0

	else					! Julian epoch ---> Time

	    if (id .lt. 2) jepoch = jepoch-2000.0d0
	    jepoch = 365.25d0*jepoch+0.5d0

	    call Time2Day8(1,u,jepoch)		! Days since 2000 Jan 1, 0 UT

	    call Time2TwoThousand(1,u,t)	! Shift to current origin

	end if

	return
	end