C+
C NAME:
C	ArrayLoc3
C PURPOSE:
C CALLING SEQUENCE:
	subroutine ArrayLoc3(iSource1,iSource2,iDestin,N,L,I1,I2,I3)
C INPUTS:
C	iSource1	integer		address of source array (loc(A))
C	iSource2	integer		address of source array (loc(B))
C	iDestin		integer		address of source array (loc(C))
C	N		integer		array size
C	L		integer		length of array element in bytes
C					(L=1: byte, L=2: int2, L=4: int4,real4)
C OUTPUTS:
C	I1, I2, I3	integer		DO loop parameters determining 
C					direction in which array is processed
C					(DO I=I1,I2,I3)
C CALLS:
C	Say
C SEE ALSO:
C	Array_Info
C PROCEDURE:
C	A=Address Source1, B=Address Source2, C=Address Destination
C	1..N : process array in forward direction (I=1,N,1)
C	N..1 : process array in backward direction (I=N,1,-1)
C
C		A<C	A=C	A>C
C	B<C	N..1	N..1	?
C	B=C	N..1	1..N	1..N
C	B>C	?	1..N	1..N
C
C	If (A=C and B=C) the direction does not matter.
C	If (A<C and B>C) or (A>C and B<C) the direction can be determined if
C	one of the source arrays does not overlap the other source array and
C	does not overlap the destination. If all three arrays overlap it is
C	not possible to obtain correct results by processing the arrays
C	sequentially (forward or backward).
C MODIFICATION HISTORY:
C	AUG-2001, Paul Hick (UCSD/CASS; pphick@ucsd.edu); added documentation
C-
	    integer	iSource1
	    integer	iSource2
	    integer	iDestin
	    integer	N
	    integer	L
	    integer	I1
	    integer	I2
	    integer	I3

	if (iSource1 .lt. iDestin) then
	    if (iSource2 .le. iDestin) then
		I1 =  N
		I2 =  1
		I3 = -1
	    else if (iSource1+N*L .le. iDestin) then
		I1 = 1
		I2 = N
		I3 = 1
	    else if (iSource2 .ge. iDestin+N*L) then
		I1 =  N
		I2 =  1
		I3 = -1
	    else
		call Say('ArrayLoc3','W','!!!!','array operation may give wrong results')
		I1 =  N
		I2 =  1
		I3 = -1
	    end if
	else if (iSource1 .eq. iDestin) then
	    if (iSource2 .lt. iDestin) then
		I1 =  N
		I2 =  1
		I3 = -1
	    else if (iSource2 .ge. iDestin) then
		I1 = 1
		I2 = N
		I3 = 1
	    end if
	else if (iSource1 .gt. iDestin) then
	    if (iSource2 .ge. iDestin) then
		I1 = 1
		I2 = N
		I3 = 1
	    else if (iSource2+N*L .le. iDestin) then
		I1 = 1
		I2 = N
		I3 = 1
	    else if (iSource1 .ge. iDestin+N*L) then
		I1 =  N
		I2 =  1
		I3 = -1
	    else
		call Say('ArrayLoc3','W','!!!!','array operation may give wrong results')
		I1 = 1
		I2 = N
		I3 = 1
	    end if
	end if

	return
	end