C+
C NAME:
C	AdjustJDCar
C PURPOSE:
C	Modifies list of start times for set of Carrington rotations
C CALLING SEQUENCE:
	subroutine AdjustJDCar(XC,nCar,JDCar,NCoff)
C INPUTS:
C	XC		real*4		modified Carrington rotation
C					Used to determine the integer offset by which
C					JDCar and NCoff are to be modified.
C	nCar		integer		# start times
C	JDCar(nCar)	real*8		start times of Carrington rotations
C					NCoff+JDCar gives the start times in Julian days
C OUTPUTS:
C	JDCar(nCar)	real*8		start times of Carrington rotations
C	NCoff		integer		integer offset
C EXTERNAL:
	external EARTH
C CALLS:
C	FLINT8, Julian, MAP_TZERO, N_CARRINGTON
C PROCEDURE:
C	Entries in JDCar are made as small as possible by subtracting
C	an integer number of rotations. NCoff is updated correspondingly
C	(same integer added).
C	This is something of a fudge intended to maintain as much precision as
C	possible in all time determinations based on JDCar.
C-
	    real		XC
	    integer		nCar
	    double precision	JDCar(nCar)
	    integer		NCoff

	double precision	JD
	double precision	JEpoch
	double precision	FLINT8

	JD = FLINT8(1,nCar,JDCar,dble(XC),0d0)
	JD = JD-120d0
	call Julian(1,iYr,Doy,JD,JEpoch)

	call MAP_TZERO(EARTH,iYr,Doy,.01,nCar,JDCar)
	NCoff0 = N_CARRINGTON(iYr,Doy)

	XC = NCoff+XC-NCoff0
	NCoff = NCoff0

	return
	end