C+
C NAME:
C	THOM_WTF
C PURPOSE:
C	Determines the intensity contribution from single electron at
C	specified location on line of sight
C CALLING SEQUENCE:
	function THOM_WTF(ScSun,ElSc,Elo,iChan)
C INPUTS:	(read-only)
C	ScSun	real	distance of spacecraft from Sun in AU
C	ElSc	real	distance of spacecraft from electron in AU
C	Elo	real	elongation of s/c line of sight (l.o.s.) in degrees.
C		Elo = 0 is the direction to the Sun
C	iChan	integer	channel ID used for setting limb darkening
C			coefficient and solar luminosity
C		1 = Helios U channel
C		2 = Helios B channel
C		3 = Helios V channel
C OUTPUTS:
C	THOM_INT real	Thomson scattering intensity in S10 units
C PROCEDURE:
C	The program is based on Chapter 6, Section B of Billings
C	"A guide to the solar corona".
C
C	The constant 835.9088 = SIGMA/2.*AU*DEG2/RSun**2*E14
C	where SIGMA is the Thomson scattering cross section
C       (7.94x10^-26 cm**2/sterrad); AU is the astronomical unit in
C	cm; DEG2 is a opening angle of (pi/180)**2 sterrad
C	around the line of sight; RSun is the solar radius in AU.
C   >	U is the limb darkening coefficient for light LT. From a graph in
C	RAUMFAHRTFORSCHUNG by LEINERT et al. LAMBDA=3650,4300,5250 A for U,B,V
C	light. From Allen (1985), p. 171, U=0.80,0.77,0.62 by linear
C	interpolation.
C   >	LUM is the luminosity of the solar disk in E14 S10 units:
C	LUM = LSUN/LS10 = 10**((10-MSUN)/2.5) in units of 10^14,
C       with MSUN (from Allen) -25.96,-26.09,-26.73 for U,B and V
C       light respectively.
C MODIFICATION HISTORY:
C	1990, Paul Hick (UCSD)
C-
	real*8	S, S2, C2, C, G
	real	U(3)	/0.80,0.77,0.62/
	real	LUM(3)	/2.421029,2.728978,4.920395/
        real	RSun	/4.652402E-3/

	ScSun2 = ScSun*ScSun
	D2 = 2.0*ScSun*cosd(Elo)
	U1 = U(iChan)
	U2 = 1.0-U1

	ElSun2	= ScSun2+ElSc*(ElSc-D2)	! El-Sun dist by cosine rule
	ElSun	= sqrt(ElSun2)
	S	= RSun/ElSun		! Sine(Omega)
	S2	= S*S
	C2	= 1.0-S2
	C	= dsqrt(C2)		! Cosine(Omega)
	G	= dlog((1.0+S)/C)

	!-------
	! Coefficients (from Billings, p. 150)

	AA	= C*S2					! Eq. (20)
	BB	= -(1.0-3.0*S2-C2*(1.0+3.0*S2)*G/S)/8.0	! Eq. (21)
	CC	= 4.0/3.0-C-(C*C2/3.0)			! Eq. (22)
	DD	= (5.0+S2-C2*(5.0-S2)*G/S)/8.0		! Eq. (23)

	DIT	= U2*CC+U1*DD				! Eq. (18)
	DITMDIR	= (U2*AA+U1*BB)*(ScSun/ElSun*sind(Elo))**2 ! Eq. (19)
	DIR	= DIT-DITMDIR

	!THOM_WTF = DIT+DIR

	THOM_WTF = 835.9088*LUM(iChan)/(1.0-U(iChan)/3.0)*(DIT+DIR)

	return			! Brightness [S10]
	end