PRO qRemoteView_Histogram, state, fovcube=fovcube

;+
; NAME:
;	qRemoteView_Histogram
; PURPOSE:
;	Displays a histogram for the current 3D data matrix
; CATEGORY:
;	Widgets: qRemoteView
; CALLING SEQUENCE:
;	qRemoteView_Histogram, state
; INPUTS:
;	state		array[1]; type: structure
;					qRemoteView state structure
; OUTPUTS:
;	(qBar display)
; INCLUDE:
	@compile_opt.pro		; On error, return to caller
; CALLS:
;	qBar, InitVar
; PROCEDURE:
;	Feeds the currently selected data cube to the qBar widget
; STATE INFO USED:
;	widget_control, state.wid_matrix, get_uvalue=ptrs, /no_copy
;	i = widget_info(state.wid_list, /droplist_select)
;	widget_control, state.wid_list, get_uvalue=list  &  list = list[i]
; STATE INFO MODIFIED:
;	widget_control, state.wid_matrix, set_uvalue=ptrs, /no_copy
; MODIFICATION HISTORY:
;	MAY-2000, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
;-

InitVar, fovcube, /key

CASE fovcube OF
0: BEGIN
	wid_p = state.wid_matrix
	wid_h = state.wid_mhisto
	ytitle = '# Volume elements'
END
1: BEGIN
	wid_p = state.wid_calc
	wid_h = state.wid_vhisto
	ytitle = '# Voxels'
END
ENDCASE

widget_control, wid_p, get_uvalue=ptrs, /no_copy

IF n_elements(ptrs) NE 0 THEN BEGIN
	i = widget_info(state.wid_list, /droplist_select)
	widget_control, state.wid_list, get_uvalue=list  &  list = list[i]
	space = strpos(list, ' ')

	title  = 'CR '+strmid(list,0,space)
	xtitle = strmid(list,space+1)

	IF xtitle EQ 'density' THEN BEGIN
		zmin = 0
		zmax = 25
		zbin = 1
	ENDIF ELSE IF xtitle EQ 'velocity' THEN BEGIN
		zmin = 300
		zmax = 1200
		zbin = 10
	ENDIF

	qbar, /histo, *ptrs[i], group=wid_h, title=title, xtitle=xtitle, ytitle=ytitle,	$
		zmin=zmin, zmax=zmax, zbin=zbin

	widget_control, wid_p, set_uvalue=ptrs, /no_copy
ENDIF

RETURN  &  END