pro qset_page_submit, state, event

@compile_opt.pro		; On error, return to caller

;+
; NAME:
;	qset_page_submit
; PURPOSE:
;	Assembles settings from qset_page for a call to set_page; destroys
;	the qset_page widget after calling set_page
; CATEGORY:
;	Widget qset_page
; CALLING SEQUENCE:
;	qset_page_submit, state, event
; INPUTS:
;	state		array[1]; type: structure
;					qset_page state structure
;	event		array[1]; type: structure
;					event structure send by 'Print' widget
; OUTPUTS:
;	(none)
; CALLS:
;	set_page
; PROCEDURE:
;	The states of all relevant widgets are picked up, and used to set up the
;	keywords for the call to set_page.
; MODIFICATION HISTORY:
;	APR-2000, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
;-

widget_control, state.wid_xsize, get_value=xsize
widget_control, state.wid_ysize, get_value=ysize

widget_control, state.wid_portrait, get_uvalue=portrait

widget_control, state.wid_eps, get_uvalue=eps
widget_control, state.wid_gif, get_uvalue=gif
widget_control, state.wid_png, get_uvalue=png
widget_control, state.wid_bmp, get_uvalue=bmp

if eps or gif or bmp or png then begin
	widget_control, state.wid_file, get_value=File
	File = File[0]
endif

; /printer is ignored if 'File' exists

set_page, file=File, bigsize=xsize, smallsize=ysize, portrait=portrait, /printer, /notwin

widget_control, event.handler, /destroy

return  &  end