;+
; NAME:
;	qLine_YBase
; PURPOSE:
;	Set up the widget for the y-axis parameters
; CATEGORY:
;	Widget qLine
; CALLING SEQUENCE:
	PRO qLine_YBase, state, event
; INPUTS:
;	state			array[1]; type: structure
;						qLine state structure
;	event			array[1]; type: structure
;						QPLOT_STRUCTURE event containing plot parameters for all curves
; OUTPUTS:
;	(creates widgets)
; INCLUDE:
	@compile_opt.pro			; On error, return to caller
; PROCEDURE:
;	Creates groups of widgets for individual curves. The whole group of widgets is
;	contained in state.wid_ybase, which is a child widget of state.wid_xbase.
; MODIFICATION HISTORY:
;	FEB-2000, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
;-

IF state.n GT 0 THEN BEGIN
	IF widget_info(state.wid_ybase,/valid) THEN widget_control, state.wid_ybase, /destroy

	yy = *state.y

	state.wid_ybase = widget_base(state.wid_xbase, /row, uvalue=-1)

	; First make a column of exclusive button widgets for setting the x-axis variable

	ybase = widget_base(state.wid_ybase, /column, /exclusive)
		FOR i=0,(state.n < state.nmax)-1 DO BEGIN
			uvalue = event.isx EQ i
			state.wid_isx[i] = widget_button(ybase, value='', uvalue=uvalue, ysize=35)
			widget_control, state.wid_isx[i], set_button=uvalue
			IF uvalue THEN BEGIN
				widget_control, state.wid_ybase, set_uvalue=i
				isx = i
			ENDIF
		ENDFOR

	; Make a column of row widgets, each row applying to one of the individual curves.

	ybase = widget_base(state.wid_ybase, /column)

	FOR i=0,(state.n < state.nmax)-1 DO BEGIN
		dummy1 = widget_base(ybase, /row, ysize=35)

			state.wid_sequence[i] = cw_field(dummy1, value=event.sequence[i], /integer, title='Y', /row, xsize=2, /return_ev)

			state.wid_ymin[i] = cw_field(dummy1, value=event.ymin[i], /floating, title='Min', /row,xsize=6, lxsize=20, /return_ev)
			state.wid_ymax[i] = cw_field(dummy1, value=event.ymax[i], /floating, title='Max', /row,xsize=6, lxsize=20, /return_ev)

			dummy2 = widget_base (dummy1, /row, /nonexclusive)
				state.wid_skip[i]		= widget_button(dummy2, value='skip'	, uvalue=event.skip[i])

				sensitive = 1B-event.skip[i]
				state.wid_newyaxis[i]	= widget_button(dummy2, value='y-axis'	, uvalue=event.newyaxis[i]	, sensitive=sensitive)
				state.wid_fit	  [i]	= widget_button(dummy2, value='fit'		, uvalue=0B, sensitive=sensitive)

				sensitive = sensitive and event.newyaxis[i]
				state.wid_exact   [i]	= widget_button(dummy2, value='exact'	, uvalue=0B					, sensitive=sensitive or i eq isx)
				state.wid_ynozero [i]	= widget_button(dummy2, value='ynoz'	, uvalue=event.ynozero [i]	, sensitive=sensitive)
				state.wid_ylog    [i]	= widget_button(dummy2, value='log'		, uvalue=event.ylog[i]		, sensitive=sensitive)

				sensitive = 1B-event.skip[i] and event.sigma_index[i] ne 0
				state.wid_use_sigma[i]	= widget_button(dummy2, value='use sigma',uvalue=event.use_sigma[i], sensitive=sensitive)


				widget_control, state.wid_skip		[i], set_button=event.skip    	[i]
				widget_control, state.wid_newyaxis	[i], set_button=event.newyaxis	[i]
				widget_control, state.wid_exact		[i], set_button=event.exact		[i], set_uvalue=event.exact[i]
				widget_control, state.wid_ynozero	[i], set_button=event.ynozero	[i]
				widget_control, state.wid_ylog		[i], set_button=event.ylog		[i]
				widget_control, state.wid_use_sigma	[i], set_button=event.use_sigma	[i]

			state.wid_sigma_index[i] = cw_field(dummy1, value=event.sigma_index[i], /integer, title=' ', /row, xsize=2 ,/return_ev)
			state.wid_linestyle  [i] = cw_field(dummy1, value=event.linestyle  [i], /integer, title='style', /row, xsize=2, /return_ev)

			state.wid_ytitle	 [i] = cw_field(dummy1, value=event.ytitle[i], /string, title='title', /row,xsize=20, /return_ev)

	ENDFOR

ENDIF

RETURN  &  END