FUNCTION qImage_cw_Slider, state

;+
; NAME:
;	qImage_cw_Slider
; PURPOSE:
;	Process messages from the slider widgets
; CATEGORY:
;	Compound widget qImage_cw
; CALLING SEQUENCE:
;	Result = qImage_cw_Slider(state)
; INPUTS:
;	state		array[1]; type: structure
;					qImage_cw state structure
; OUTPUTS:
;	Result		scalar; type: byte
;					1B: display needs to be refreshed completely
;						(by call to qImage_cw_Set_Value)
;					0B: display does not need to be redrawn
; INCLUDE:
	@compile_opt.pro			; On error, return to caller
; PROCEDURE:
; STATE INFO USED:
;	widget_control, state.wid_tool, get_uvalue=tool
; MODIFICATION HISTORY:
;	FEB-2000, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
;-

widget_control, state.wid_xslide, get_value=ix, get_uvalue=jx
widget_control, state.wid_yslide, get_value=iy, get_uvalue=jy

widget_control, state.wid_tool, get_uvalue=tool_state, /no_copy
zoom = tool_state.send.zoom_uval
widget_control, state.wid_tool, set_uvalue=tool_state, /no_copy

dbox = [ix-jx,iy-jy]/zoom

qImage_cw_Box, state, box, /get
qImage_cw_Box, state, box+dbox#[1,1], /put

IF dbox[0] NE 0 THEN widget_control, state.wid_xslide, set_uvalue=ix, /no_copy
IF dbox[1] NE 0 THEN widget_control, state.wid_yslide, set_uvalue=iy, /no_copy

RETURN, 1  &  END