;+
; NAME:
;	vu_vox_draworbit
; PURPOSE:
;	Internal use by vu_vox only
; CALLING SEQUENCE:
	FUNCTION vu_vox_draworbit, F, ut, hdr, zero_lng, cntr, dvox, obj_val
; CATEGORY:
;	Volume Pro board
; INCLUDE:
	@compile_opt.pro			; On error, return to caller
; CALLS:
;	gridgen, TimeSet, TimeUnit, TimeOp, big_eph, jpl_body, CvSky
; MODIFICATION HISTORY:
;	SEP-2001, Kevin Nguyen, Paul Hick (UCSD/CASS)
;	OCT-2006, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
;		Replaced NewcombSun by big_eph
;-
n = 366
P = TimeSet(/diff, day=gridgen(n, range=-n/2+[0,n-1]))

P = TimeOp(/add, ut, P)						; One year centered on ut in steps of 1 day

P = big_eph(P		, $						; Ecliptic positions of Earth over one year
		body = jpl_body(/earth,/string) , $
		/to_ecliptic, $
		/to_sphere	, $
		/degrees	, $
		/precess	, $
		/onebody	, $
		/silent 	)

; Convert to heliographic locations at the matrix time ut

P = CvSky(ut, from_ecliptic=P, /to_heliographic, /degrees, /silent)

;P = P-[zero_lng,0,vu_get(hdr,/distance_start)]#replicate(1,n)
P[0,*] = P[0,*]-zero_lng

P = cv_coord(from_sphere=P, /to_rect, /degrees)

P = round( cntr+P*dvox )

F[P[0,*], P[1,*], P[2,*]] = obj_val

RETURN, F  &  END