;+
; NAME:
;	vu_prefix
; PURPOSE:
;	Get file name prefix to be used for locating output files
;	from the tomography.
; CATEGORY:
;	sat/idl/util/vupack
; CALLING SEQUENCE:
	FUNCTION vu_prefix, magnetic=magnetic, fast=fast, silent=silent, error=error
; OPTIONAL INPUT PARAMETERS:
;	/magnetic			if not set then the filter for the plasma
;						data is returned (see PROCEDURE).
;						if set then the filter for magnetic data
;'						is returned (see PROCEDURE).
;	/fast				if set then the filter for time-dependent
;						tomography is returned.
;						if not set then env var $fast is checked
;						if not set and env var $fast is not defined
;						then the filter for corotating tomography
;						is returned.
;	silent=silent
; OUTPUTS:
; OPTIONAL OUTPUT PARAMETERS:
; INCLUDE:
	@compile_opt.pro		; On error, return to caller
; CALLS:
;	InitVar, IsType
; PROCEDURE:
;	If /magnetic NOT set:
;	- first check env var $NV_PREFIX
;	- if it doesn't exist, check for env var $NV_PREFIX_'kind'
;		where 'kind' = 'slow' or 'fast' (depending on setting of /fast)
;	- if neither env var exists use the default 'nv3d' if /fast NOT set,
;		or 'nv3f' if /fast SET.
;
;	If /magnetic SET:
;	- first check env var $BB_PREFIX
;	- if it doesn't exist, check for env var $BB_PREFIX_'kind'
;		where 'kind' = 'slow' or 'fast' (depending on setting of /fast)
;	- if neither env var exists use the default 'wson'.
; MODIFICATION HISTORY:
;	AUG-2004, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
;-

InitVar, magnetic, /key
InitVar, fast	 , /key
InitVar, error	 , 0
InitVar, silent  , 0

;IF IsType(fast, /undefined) THEN BEGIN
;	fast = getenv('fast')
;	IF fast eq '' THEN fast = 0 ELSE fast = fix(fast)
;ENDIF

kind = (['slow','fast'])[fast]

CASE magnetic OF
0: BEGIN
	prefix = getenv('NV_PREFIX')
	IF prefix EQ '' THEN prefix = getenv('NV_PREFIX_'+strupcase(kind))
	IF prefix EQ '' THEN prefix = ([['nv3d','nv3f'],['err1','err1'],['err2','err2']])[fast,error]
	IF silent LE 0  THEN message, /info, kind+' nv prefix is '+prefix
END
1: BEGIN
	prefix = getenv('BB_PREFIX')
	IF prefix EQ '' THEN prefix = getenv('BB_PREFIX_'+strupcase(kind))
	IF prefix EQ '' THEN prefix = ([['wson','wson'],['err1','err1'],['err2','err2']])[fast,error]
	IF silent LE 0  THEN message, /info, kind+' bb prefix is '+prefix
END
ENDCASE

RETURN, prefix  &  END