;+
; NAME:
;	vu_nagoyasourcemap
; PURPOSE:
;	Overplot IPS sources for given day on a sky map derived from a
;	tomographic reconstruction.
; CATEGORY:
;	IPS forecast: WWW
; CALLING SEQUENCE:
	PRO vu_nagoyasourcemap, ut0=ut0, degrees=degrees, _extra=_extra,	$
		utnoon=utnoon, point_sources=point_sources, geolng=geolng, nosweep=nosweep
; INPUTS:
;	ut0=ut0		array[1]; type: time structure
;					Defines the time (UT) for the skymap
;					A scalar is interpreted as the difference between local
;					time and UT, and is used to get a UT from the system time.
;					If absent then T = 8 is assumed (offset PST and UT)
; OPTIONAL INPUT PARAMETERS:
;	geolng=geolng	scalar; type: float
;						geographic longitude of Nagoya.
;	point_sources=point_sources
;					array; type: ips_point_source structure
;
;					Both arguments are calculated internally if not specified
;
;	/degrees	if set then all angles are in degrees (default: radians)
;
;	/ips_speed	if set, plot IPS speed values
;	/ips_glevel	if set, plot IPS g-level values
;
;	maxelo		scalar; type: float
;					if set and non-zero then a fish-eye map is plotted out to
;					elongation 'maxelo'. By default a Hammer-Aitoff map is drawn
;	/equator		if set, the 'horizontal' in the sky map is parallel to the
;						equatorial plane. By default the horizontal is along the ecliptic
;	/names		if set, then the names of the point sources are plotted
;
; OPTIONAL OUTPUT PARAMETERS:
;	UTnoon			array; type: time structure
;						UT for previous time when Sun crossed local
;						meridian (i.e. local noon)
; INCLUDE:
	@compile_opt.pro				; On error, return to caller
; CALLS:
;	Carrington, destroyvar, TimeUnit, GeographicInfo, TimeGet, TimeOp
;	InitVar, IsType, TimeSet, getnagoyasources, vu_earthskymap
; PROCEDURE:
; MODIFICATION HISTORY:
;	MAR-2000, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
;-

InitVar, nosweep, /key

ut = Carrington(ut0, /get_time)

IF IsType(geolng, /undefined) THEN	$
	GeographicInfo, /nagoya, geolng=geolng, degrees=degrees

nsources = -1
ncount = 0

REPEAT BEGIN
	IF nsources NE -1 THEN BEGIN
		ncount = ncount+1			; Skip back 24 hours
		ut = TimeOp(/add,ut,TimeSet(/diff,hour=-24))
	ENDIF
									; Find time of preceding noon
	GeographicInfo, ut, /nagoya, /previous, utnoon=UTnoon

	message, /info, 'UT: '+TimeGet(ut,/ymd)+'; previous noon, UT: '+TimeGet(utnoon,/ymd)

	nsources = n_elements(point_sources)

	IF nsources EQ 0 THEN BEGIN
		trange   = TimeOp(/add, utnoon, TimeSet(/diff,hour=[-12,12]))
		nsources = getnagoyasources(trange, degrees=degrees, point_sources=point_sources)
	ENDIF

ENDREP UNTIL nsources NE 0 OR ncount GT 10


CASE nosweep OF
0:	ut = utnoon
1: BEGIN
	ut = ut0
	destroyvar, geolng
END
ENDCASE

IF nsources NE 0 THEN vu_earthskymap, ut0=ut, /nodata,	$
		geolng=geolng, point_sources=point_sources, degrees=degrees, _extra=_extra

RETURN  &  END