;+
; NAME:
;	ThomsonSoup
; PURPOSE:
;	(Used internally only).
;	Calculates constant needed for calculating Thomson scattering intensities
; CALLING SEQUENCE:
	PRO ThomsonSoup, ElSun, U, It, Itr, aa=AA,bb=BB,cc=CC,dd=DD
; INPUTS:
;	ElSun		array[*]		Electron-Sun distance in solar radii (=1./sine(Omega))
;	U			array[*],scalar	limb darkening constant
; OUTPUTS:
;	rIt,rItr	real		constants
; INCLUDE:
	@compile_opt.pro		; On error, return to caller
; RESTRICTIONS:
;	Distance ElSun must be greater than one solar radii
;	(if its smaller then ElSun=1 is used)
; PROCEDURE:
; >	See Billings, Guide to the solar corona (Chapter 6, p. 150) Academic Press (1966)
; >	The constants are functions of the angular size, Omega, of the Sun as seen from the
;	electron, and the limb darkening constant U. Sin(Omega)=RSun[cm]/dElectronSun[cm].
; MODIFICATION HISTORY:
;	JUL-1996, Paul Hick (UCSD)
;-

S	= (1d0/ElSun) < 1				; Sin(Omega)
S2	= S*S
C2	= (1-S2) > 0
C	= sqrt(C2)						; Cos(Omega)
G	= C2/S*alog((1+S)/C)

AA	= C*S2							; Eq. (20)
BB	= -(1-3*S2-G*(1+3*S2))/8		; Eq. (21)
CC	= 4/3d0-C-(C*C2/3)				; Eq. (22)
DD	= (5+S2-G*(5-S2))/8				; Eq. (23)

V	= 1-U
It	= V*CC+U*DD						; Eq. (18), It
Itr = V*AA+U*BB	 					; Eq. (19), It-Ir

RETURN  &  END