;+
; NAME:
;	ThomsonElectronFar
; PURPOSE:
;	Determines the intensity scattered from single coronal electron
;	by Thomson scattering in the limit of large electron-Sun distance
;	(limit Omega->0; ElSun->Infinity)
;
;	Get Thomson scattering brightness of one electron per square degree
;	of sky in S10 units in limit of large electron-Sun distance
; CALLING SEQUENCE:
	FUNCTION ThomsonElectronFar, SinChi, P, rsun=RSun, au=au, apm=APM, s10=S10
; INPUTS:
;	SinChi		array; type: float
;					sine of angle Sun-Electron-Observer
; OPTIONAL INPUT PARAMETERS:
;	APM			array; type: float
;					apparent magnitude of the Sun
;	rsun=RSun	array; type: float
;					distance Sun-Electron (in solar radii)
; OUTPUTS:
;	Result		array; type: float
;					scattered intensity; units depend on /S10 setting
;					S10 NOT set: 10^-26 times the flux from the solar disk incident on the electron
;					S10 set    : 10^-26 S10
;	P			array	polarization	(-1<=P<=1)
; INCLUDE:
	@compile_opt.pro		; On error, return to caller
; CALLS:
;	ThomsonS10, InitVar, ToSolarRadii
; PROCEDURE:
; >	Based on Chapter 6, Section B of Billings' "A guide to the solar
;	corona" (p. 150)
;
;	Sigma	= Thomson cross section=7.96x10^-26 cm^2/sterad
;	Omega	= angular size of Sun from electron
;	Chi	= angle Sun-Electron-Observer
;	I0	= intensity at disk center
;	RSun	= solar radius = 7x10^10 cm
;
;	Billings specifies the scattered intensity in the form
;		I=0.5*Pi*Sigma*I0*Func(Omega,Chi) (erg/s/sterad)
;	The average intensity coming from the solar disk is
;		i=(Pi*RSun^2)*I0*(1-U/3) (erg/s/sterad)
;	The flux incident on the electron is F=i/ElSun^2 (erg/s/cm^2)
;	The ratio
;		I/F = 0.5*Sigma*Func(Omega,Chi)/( (RSun/ElSun)^2*(1-U/3) )
;	is returned here, except for a factor 10^-26 (from Sigma).
; >	The flux received from the solar disk by the observer (rather than the
;	electron) is i/ScSun^2 = F*(ElSun/ScSun)^2 (erg/s/cm^2).
;	The scattered flux from the electron incident on the observer is
;	I/ScEl^2 (erg/s/cm^2). The ratio (I/F)*(ScSun/(ElSun*ScEl))^2 gives
;	the flux received from the electron in units of the flux received by
;	the observer from the solar disk.

; >	An S10 unit is `the brightness of one 10th magnitude star per square
;	degree of sky'. Replace the star by an electron at the same location
;	in the sky, and at distance ScEl away from the observer. The electron
;	is radiating by Thomson scattering of sunlight.
; >	STEP 1: Calculate the intensity (erg/s/sterad) -emitted- by the electron
;		in units of the flux -incident- at 1 AU from the solar
;		disk (erg/s/cm^2) (compare ThomsonElectron; the only difference
;		is that ElSun is replaced by r0=1 AU in the unit determination)
; >	STEP 2: Convert to units of the flux -incident- at 1 AU from a 10th
;		magnitude star: multiply by 10^((10-M)/2.5). (Apparent
;		magnitude, M=-2.5*log(Flux)).
;	!!! M is an apparent magnitude as observed at 1 AU. This is why
;		1 AU was used in step 2, rather than the observer-Sun
;		distance ScSun.
; >	10^-48 = 10^-26*10^-26*10^4:
;	10^-26 from Sigma; 10^-26 from 1/ScEl^2; 10^4 from 10^(10/2.5)
; MODIFICATION HISTORY:
;	JUL-1996, Paul Hick (UCSD)
;-

InitVar, S10, /key

S  = SinChi*SinChi
S2 = 2-S
P  = S/S2

CASE S10 OF
0: tmp = 1.0
1: tmp = ThomsonS10(RSun*ToSolarRadii(au=au),APM)
ENDCASE

RETURN, tmp*0.5*!physics.thomsoncrosssection*S2  &  END