;+
; NAME:
;	www_help_clean
; PURPOSE:
;	Replaces any occurrence of HTML reserved characters (<,>,&,")
;	with the appropriate HTML counterpart.
; CATEGORY:
;	www_help
; CALLING SEQUENCE:
	PRO www_help_clean, txt
; INPUTS:
;	txt		array; type: string
;				text to be checked
; OUTPUTS:
;	txt		array; type: string
;				updated input array
; INCLUDE:
	@compile_opt.pro		; On error, return to caller
; PROCEDURE:
; >	Ampersands:			 &  --->	&amp.
;	Since ampersands are special HTML characters this replacement must be done first.
; >	Left angle brackets: <	---> &lt;
; >	Right angle brackets:>  ---> &gt;
; > Double quotes		 "  --->  &quot;
; MODIFICATION HISTORY:
;	JAN-2001, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
;-

FOR i=0L,n_elements(txt)-1 DO BEGIN
	txt[i] = strjoin( strtok(txt[i],'&', /extract, /preserve_null), '&amp;' )
	txt[i] = strjoin( strtok(txt[i],'<', /extract, /preserve_null), '&lt;'  )
	txt[i] = strjoin( strtok(txt[i],'>', /extract, /preserve_null), '&gt;'  )
	txt[i] = strjoin( strtok(txt[i],'"', /extract, /preserve_null), '&quot;')
ENDFOR

RETURN  &  END