FUNCTION TimeGST, T, degrees=degrees

;+
; NAME:
;	TimeGST
; PURPOSE:
;	Calculate Greenwich Sidereal Time from UT
;	Good for years 1901 through 2099. Accuracy is 0.006 degree.
; CATEGORY:
;	Celestial mechanics
; CALLING SEQUENCE:
;	gst = TimeGST(T, /degrees)
; INPUTS:
;	T			array; type: time structure
;					universal time (UT)
; OPTIONAL INPUT PARAMETERS:
;	/degrees	if set output is in degrees (default: radians)
; OUTPUTS:
;	gst			array; type: double
;					Greenwich sidereal time
; INCLUDE:
	@compile_opt.pro		; Return to caller
; CALLS:
;	TimeOp, TimeSet, TimeUnit, TimeGet, ToDegrees
; RESTRICTIONS:
;	Only valid for years 1901 through 2099
; PROCEDURE:
;	Local Sidereal Time (LST) is defined as the Hour Angle of the
;	vernal equinox. GST is RA of local meridian at Greenwich
; MODIFICATION HISTORY:
;	See: C.T. Russell, Geophysical Coordinate Transformations,
;		in: Cosmic Electrodynamics 2 (1971) 184-196
;-

; # Days since 1899 Dec 31.5 (Julian epoch 1900.0)

RETURN, ( ( 279.690983d0  		$
	+0.9856473354d0*TimeOp(/subtract, T, TimeSet(jepoch=1900), TimeUnit(/day))		$
	+		  360d0*TimeGet(T, /fotime, /day, /full)	$
	+180d0 ) mod 360d0 ) /ToDegrees(degrees=degrees)

END