pro nso_fe_plot, 	$
	line		= line			,	$
	rotation	= rotation		,	$
	limb		= limb			,	$
	height		= height		,	$
	silent		= silent		,	$
	_extra		= _extra

@compile_opt.pro			; On error return to caller

;+
; NAME:
;	nso_fe_plot
; PURPOSE:
;	Plot synoptic maps for Fe XIV and Fe X data
; CALLING SEQUENCE:
;	nso_fe_plot
; OPTIONAL INPUTS:
;	All input keywords for href=nso_fe_read= are permitted.
; OPTIONAL OUTPUTS:
; CALLS:
;	InitVar, nso_fe_read, TimeOp, TimeSet, TimeUnit, Carrington
;	PlotSynopticMap
; PROCEDURE:
;>	Green and red maps are calibrated using the constant calibration
;	for post-1989 observations.
;>	Temperatures are calculated by taking ratios of the green and red
;	arrays, i.e. this assumes that the first scan of green and red map
;	are taken at the same time.
; MODIFICATION HISTORY:
;	SEP-2003, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
;-

InitVar, silent, 0

map = nso_fe_read(_extra=_extra, silent=silent, error=error,	$
	line=line, rotation=rotation, limb=limb, height=height, utstart=utstart)

case error eq '' of
0: message, /info, error
1: begin

	xcmap = [utstart, TimeOp(/add,utstart,TimeSet(day=(size(map,/dim))[0]-1))]
	xcmap = Carrington(xcmap)

	xstub =  40.0/360.0						; Extra room on either side of map
	xcdisplay = rotation+[0,1]+xstub*[-1,1]
	ylmap = 90*[-1,1]

	PlotSynopticMap, xcdisplay, map,	$
		xcmap=xcmap,	$
		ylmap=ylmap,	$
		/degrees,		$
		/timeaxis,		$
		_extra=_extra

end
endcase

return  &  end