C+
C NAME:
C	Time2EclipticEquatorial
C PURPOSE:
C	Converts ecliptic coordinates into equatorial coordinates or v.v.
C CATEGORY:
C	Math: coordinate transformation
C CALLING SEQUENCE:
	subroutine Time2EclipticEquatorial(id,tt,phi,lat)
C CALLS:
C	Time2JEpoch, rotated
C INPUTS:
C	id	integer			id=0: ecliptic     ---> equatorial
C					id=1: equatorial   ---> ecliptic
C	tt(2)	integer			2-element standard time of current date
C	phi	double precision	ecliptic longitude/right ascension for equinox of current date
C	lat	double precision	ecliptic latitude/declination for equinox of current date
C OUTPUTS:
C	phi	double precision	right ascension/ecliptic longitude
C	lat	double precision	declination/ecliptic latitude
C CALLS:
C	Time2JEpoch, rotated
C PROCEDURE:
C	See O. Montenbruck, Practical Ephemeris Calculations, p. 11
C	If ID not equal 0 or 1 then ID = 0 is assumed.
C MODIFICATION HISTORY:
C	JAN-2004, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
C-
	    integer		id
	    integer		tt(2)
	    double precision	phi
	    double precision	lat

	double precision	eps
	double precision	jepoch
	double precision	beta

	call Time2JEpoch(2,1,tt,jepoch)		! Get Julian epoch (-2000)
	eps = 23.439291d0-0.00013004d0*jepoch	! Angle (ecliptic-equator)

	beta = eps				! To equatorial coord
	if (id .eq. 1) beta = -beta		! To ecliptic coord

	call rotated(90d0, beta, -90d0, phi, lat)

	return
	end