C+
C NAME:
C	ThomsonSoup
C PURPOSE:
C	(Used internally only).
C	Calculates constants needed for Thomson scattering intensities
C CALLING SEQUENCE:
	subroutine ThomsonSoup(ElSun,U,rIt,rItr)
C INPUTS:
C	ElSun	real	Electron-Sun distance (in solar radii) = 1./sine(Omega)
C	U	real	limb darkening constant
C OUTPUTS:
C	rIt,rItr real	constants
C RESTRICTIONS:
C	ElSun is restricted to values larger than one solar radius.
C	(smaller values are treated as equal to one solar radius).
C PROCEDURE:
C >	See Billings, Guide to the solar corona (Chapter 6, p. 150)
C	Academic Press (1966)
C >	The constants are functions of the angular size, Omega, of the
C	Sun as seen from the electron, and the limb darkening constant U.
C	Sin(Omega) = RSun/dElectronSun.
C MODIFICATION HISTORY:
C	JUL-1996, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
C-
	    real	ElSun
	    real	U
	    real	rIt
	    real	rItr

	double precision	S
	double precision	S2
	double precision	C2
	double precision	C
	double precision	G

	S	= min(1d0/ElSun,1d0)		! Sine(Omega)
	S2	= S*S
	C2	= 1-S2
	C	= dsqrt(C2)			! Cosine(Omega)
	G	= C2/S*dlog((1+S)/C)

	AA	= C*S2				! Eq. (20)
	BB	= -(1-3*S2-G*(1+3*S2))/8	! Eq. (21)
	CC	= 4d0/3-C-(C*C2/3)		! Eq. (22)
	DD	= (5+S2-G*(5-S2))/8		! Eq. (23)

	V	= 1-U
	rIt	= V*CC+U*DD			! Eq. (18), It
	rItr	= V*AA+U*BB	 		! Eq. (19), It-Ir

	return
	end