C+
C NAME:
C	ThomsonLOSFar
C PURPOSE:
C	Determines the integrated intensity along a line of sight for electron
C	Thomson scattering in the limit of small angular size of the Sun
C	for a 1/r^2 density.
C CALLING SEQUENCE:
	function ThomsonLOSFar(SLower,SUpper,ScSun,Elo, P)
C INPUTS:	(the input values are retained on return):
C	SLower	real	lower limit of integration (solar radii)
C	SUpper	real	upper limit of integration (solar radii)
C			If SUpper<0 the upper limit is effectively infinity:
C			      SUpper is set to the parameter MATH__PINF (=1.e30) solar radii
C	ScSun	real	heliocentric distance of observer (solar radii)
C	Elo	real	elongation of s/c line of sight (l.o.s.) in degrees.
C			(Elo=0 is the direction to the Sun)
C OUTPUTS:
C	ThomsonLOSFar
C		real	Integrated Thomson scattering intensity received
C			per sterad in units of 10^-16 times the flux received
C			from the solar disk (at the observer location).
C	P	real	polarization
C CALLS:
C	ThomsonFarY
C INCLUDE:
	include		'sun.h'
	include		'phys.h'
	include		'math.h'
C PROCEDURE:
C	See href=ThomsonLOS=
C	Density at 1 AU of 5 cm^-3 is assumed.
C MODIFICATION HISTORY:
C	1996, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
C-
	    real	SLower
	    real	SUpper
	    real	ScSun
	    real	Elo
	    real	P

	parameter	(denAU = 5.0)
	real		I0
	real		I0t
	real		I0tr
	real		I1
	real		I1t
	real		I1tr

	E = MATH__RPD*Elo		! Switch to radians
	C = cos(E)

	Y0 = -C+max(SLower,0.0)/ScSun

	Y1 = MATH__PINF
	if (SUpper .ge. 0.0 .and. SUpper .ne. MATH__PINF) Y1 = -C+SUpper/ScSun

	call ThomsonFarY(Y0,E, I0,I0t,I0tr)	! At lower limit
        call ThomsonFarY(Y1,E, I1,I1t,I1tr)	! At upper limit

	ThomsonLOSFar = 0.5*PHYS__THOMSON*denAU/(ScSun*SUN__RAU)*SUN__AU*1E3*(I1-I0)

	P = 0
	if (I1 .ne. I0) P = (I1tr-I0tr)/(I1-I0)	! Polarization

	return
	end