;+
; NAME:
;	smei_star__define
; PURPOSE:
;	Defines structure to store fit parameters for stars
; CATEGORY:
;	camera/idl/star
; CALLING SEQUENCE:
	PRO smei_star__define
; INPUTS:
;	(none)
; OUTPUTS:
;	(none)
; INCLUDE:
	@compile_opt.pro		; On error, return to caller
; PROCEDURE:
;	If this structure is modified then the format statements in
;	href=smei_star_formatpnt= need to be updated accordingly.
; MODIFICATION HISTORY:
;	AUG-2006, Paul Hick (UCSD/CASS)
;		Extracted from smei_star_fit
;	NOV-2006, Jordan Vaughan (UCSD; jtvaugha@ucsd.edu)
;		Added gain field to stars_fit
;	MAY-2007, Paul Hick (UCSD/CASS)
;		Changed scalar fovxangle to 2-element array fovangle
;		Added 2-element array dfovangle
;	JUL-2007, Paul Hick (UCSD/CASS)
;		Added psfstretch, renamed dfovangle to dpsfstretch
;	FEB-2008, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
;		Added "remove" entry.
;-

stars_fit = {smei_star  	, $

	name		: ''		, $ 			; Name of star
	radec		: [0.0,0.0] , $ 			; RA/dec of star from catalogue

	maptype 	: ''		, $ 			; Type of map where star was fitted
	camera		: 0 		, $ 			; Camera

	; Based on low-res maps

	time		: ''		, $ 			; Time of observation (may need correction near edge of map)
	psfangle	: 0.0 		, $ 			; PSF rotation angle
	fovangle	: [0.0,0.0] , $ 			; Angle of centroid from camera optical axis along
	psfstretch	: [0.0,0.0] , $				; long and narrow FOV dim

	; Camera gain

	gain		: 0.0		, $				; Camera gain constant

	; Based on hi-res maps

	name_close	: ''		, $ 			; Name of nearby brighter star if star was not fitted separately
											; (if a name is in here there won't be any fit parameters)
	total_adus	: 0.0		, $
	bright_raw	: 0.0		, $ 			; Mean adus inside sky PSF after background subtraction
	bright_mdl	: 0.0 		, $ 			; Mean adus inside mdl PSF after background subtraction

	; Fit results

	bright		: 0.0 		, $ 			; Fitted brightness scale
	back_const	: 0.0		, $ 			; Fitted background
	back_slope	: [0.0,0.0]	, $ 			; RA/dec slope of background fit (ADUs/degree)
	n_bkgnd 	: 0 		, $ 			; # Pixels inside background area
	n_fitpsf	: 0 		, $ 			; # Pixels inside PSF
	stdev_bkgnd : 0.0 		, $ 			; Standard deviation of background residual
	stdev_psf	: 0.0 		, $ 			; Standard deviation of star residual inside PSF
	cvfit		: 0.0		, $ 			; Correlation coefficient of fit
	dradec		: [0.0,0.0]	, $ 			; Correction to RA/dec of catalogue location
	dpsfangle	: 0.0		, $
	dpsfstretch	: [0.0,0.0] , $ 			; Correction to direction cosine angles
	psfwidth	: [0.0,0.0] , $ 			; Estimate of PSF halfwidth perpendicular and along PSF symmetry axis

	; Leftover

	remove	 	: 0 		, $ 			; Set to 1 if subtracted from skymap
	done		: 0 		$	 			; Indicates that star was fitted (always 1)
}

RETURN  &  END