;+
; NAME:
;	smei_sky_hdr2mode
; PURPOSE:
;	Determines value of skymap 'mode' from Fits header
; CATEGORY:
;	camera/idl/sky
; CALLING SEQUENCE:
	FUNCTION smei_sky_hdr2mode, hdr
; INPUTS:
;	hdr 	array[1]; type structure
; OUTPUTS:
;	R		scalar; type: string
;				one of ['npmap','spmap','eqmap','lores']
; INCLUDE:
	@compile_opt.pro		; On error, return to caller
; PROCEDURE:
;	Usually used to determine the value for the 'mode'
;	keyword for href=cvsmei=.
; MODIFICATION HISTORY:
;	MAR-2008, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
;-

CASE IsType(hdr,/string) OF
0: BEGIN
	maptype = strlowcase(hdr.map)
	good = 1
END
1: BEGIN
	maptype = strlowcase(fxpar(hdr,'MAP'))
	good = !err GE 0
END
ENDCASE

CASE good OF

0: mode = ''

1: BEGIN

	CASE 1 OF
	(strpos(maptype,'north pole'	) NE -1): mode = 'npmap'
	(strpos(maptype,'south pole'	) NE -1): mode = 'spmap'
	(strpos(maptype,'equatorial'	) NE -1): IF strpos(maptype,'ra=[0,360],dec=[-90,+90]') NE -1 THEN mode = '' ELSE mode = 'eqmap'
	(strpos(maptype,'bad pixel map' ) NE -1): mode = ''
	ELSE									: mode = 'lores'
	ENDCASE

END

ENDCASE

RETURN, mode  &  END