C+
C NAME:
C	GAL_CNTR
C PURPOSE:
C	Flag data points close to the galactic center
C CATEGORY:
C	Data processing
C CALLING SEQUENCE:
	subroutine GAL_CNTR(iSc,iCnt,NST,NS,LL,PP,ZZ)
C INPUTS:
C	iSc		integer		1=Helios A, 2=Helios B
C	iCnt		integer		# observations
C	NST,NS		integer		range of sectors (modified sectors #)
C	LL(iCnt)	real		ecliptic longitude of Sun
C	PP(iCnt)	integer		=1,2; photometer ID
C	ZZ(NST:NS,iCnt)	real		intensities
C OUTPUTS:
C	ZZ(NST:NS,iCnt)	real		intensities
C CALLS:
C	BadR4
C SIDE EFFECTS:
C	No corrections are made for Helios B (iSc=2)
C PROCEDURE:
C	When the ecliptic longitude of a sector falls inside the range
C	specified in arrays GALMIN,GALMAX (indicating the range of ecliptic
C	longitude where the galactic center contributes significantly to the
C	signal) the intensity is flagged (set to BadR4())
C MODIFICATION HISTORY:
C	???-????, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
C-
	    integer	iSc
	    integer	iCnt
	    integer	NST
	    integer	NS

	    real	LL(iCnt)
	    integer	PP(iCnt)
	    real	ZZ(NST:NS,iCnt)

	real		WIDTH		/5.625/,
     &			GALMIN(2,2)	/233.,220.,275.,290./,
     &			GALMAX(2,2)	/283.,280.,275.,290./

	if (iSc .eq. 1) then

	    Bad = BadR4()

	    do J=NST,NS
		JS = (1+abs(2*J-1))/2
		RLNG = ( min(JS,8)+2*max(0,min(JS-8,4))+4*max(0,JS-12) )*WIDTH
		RWDTH = .25*WIDTH*( 5+sign(1,JS-9)+2*sign(1,JS-13) )!Sector halfwidth
		RLNG = RLNG-RWDTH		! Phase angle of sector center
		if (J .le. 0) RLNG = -RLNG
		RLNG0 = (3-2*iSc)*RLNG

		do I=1,iCnt
		    RLNG = LL(I)+RLNG0		! Ecliptic longitude of sector center
		    RLNG = mod(mod(RLNG,360.)+360.,360.)
		    GLOW = GALMIN(PP(I),iSc)-RWDTH
		    GHGH = GALMAX(PP(I),iSc)+RWDTH
		    if (RLNG .gt. GLOW .and. RLNG .lt. GHGH) ZZ(J,I) = Bad
		end do
	    end do

	end if

	return
	end