C+
C NAME:
C	AsymDust
C PURPOSE:
C	Converts an observed intensity in the ecliptic into an intensity as
C	would be observed in the plane of symmetry of the zodiacal dust cloud
C	(iD=0) and v.v. (iD=1)
C CATEGORY:
C	Physics: empirical correction
C CALLING SEQUENCE:
	function AsymDust(iD,iSc,L,P,iS,Z)
C INPUTS:	(all input is read-only)
C	iD	integer		=0 : convert from ecliptic to symmetry plane
C				=1 : convert from symmetry plane to ecliptic
C	iSc	integer		1=Helios A; 2=Helios B
C	L	real		ecliptic longitude of Sun
C	P	integer		photometers for first ICNT(1) measurements
C	iS	integer		sector number (regular or modified)
C	Z	real		intensity
C OUTPUTS:
C	AsymDust
C		real		transformed intensity
C				If Z = BadR4() then AsymDust returns BadR4()
C CALLS:
C	BadR4
C PROCEDURE:
C	The corrections used are from Leinert et al.: Astron. Astrophys. 110
C	(1982) 355-357
C MODIFICATION HISTORY:
C	JUN-1992, Paul Hick (UCSD/CASS; pphick@ucsd.edu)
C-
	    integer	iD
	    integer	iSc
	    real	L
	    integer	P
	    integer	iS
	    real	Z

	real		Omega		/-93./
	real		Alfa(3)		/.067,.096,.115/	! Omega=87-180
	real		Gamma(16,2)	/.007,.024,.035,.044,.050,.056,.061,.065,
     &					 .068,.068,.064,.058,.047,.034,.021,.004,
     &					 .005,.013,.019,.025,.028,.034,.038,.043,
     &					 .048,.052,.050,.046,.039,.027,.015,.004/

	Bad = BadR4()
	AsymDust = Bad

	if (Z .ne. Bad) then

	    !-------
	    ! F = Correction for not observing in plane of symmetry
	    ! G = Correction for east-west asymmetry

	    A = L-Omega
	    F = 1.+Alfa(P)*sind(A)*(2*iSc-3)
	    if (P .ne. 3) then
		J = iS
		if (iS .gt. 16) J = iS-32		! Modified sector #
		F = F*( 1.+sign(1,J-1)*Gamma((1+abs(2*J-1))/2,P)*cosd(A) )
	    end if

	    AsymDust = Z*((1-iD)/F+iD*F)
	endif
	
	return
	end